© serviceprofessionalgmbh

Ein Relikt aus alten Tagen. Holz liegt noch als CLISTe vor. Eine gute Gelegenheit es in REXX zu versuchen.

PROC 0 DEBUG
IF &DEBUG=DEBUG THEN CONTROL CONLIST
CLEAR
WRITE
WRITE
WRITE
WRITE
WRITE               ZU BEGINN KOENNEN SIE EINE ANZAHL VON
WRITE               30 ODER MEHR HOELZERN FESTSETZEN.
WRITE
WRITE               ABWECHSELND NEHMEN SIE UND ICH JEWEILS
WRITE               1 BIS 7 HOELZER WEG.
WRITE
WRITE
WRITE               WER DAS   L E T Z T E   HOLZ NEHMEN MUSS,
WRITE
WRITE               H A T      V  E  R  L  O R  E  N
WRITE
WRITE
A000:WRITENR   WIE VIELE HOELZERN BEI BEGINN  ===>
     READ &ANZ
     IF &DATATYPE(&ANZ)=CHAR THEN DO
        WRITE EINGABE NICHT NUMERISCH
        GOTO A000
     END
     CLEAR
     IF &ANZ < 30 THEN DO
        WRITE NIESELPRIEM,  DANN SPIELEN WIR EBEN MIT 30 HOLZ
        SET &ANZ=30
     END
     WRITE
     WRITENR   WOLLEN SIE BEGINNEN J / N ===>
     READ
     IF &SYSDVAL EQ N THEN GOTO A020
A010:WRITE
     WRITENR   WIEVIEL WOLLEN SIE NEHMEN ? BITTE ANZAHL EINGEBEN ===>
     READ &HOLZ
     IF &DATATYPE(&HOLZ)=CHAR THEN DO
        WRITE EINGABE NICHT NUMERISCH
        GOTO A010
     END
     IF &ANZ < &HOLZ THEN DO
        WRITE SCHNARCHER, ES SIND NUR NOCH &ANZ HOLZ VORHANDEN
        GOTO A010
     END
     IF &HOLZ GT 7 OR &HOLZ LT 1 THEN DO
        WRITE ES IST NUR EINE ZAHL VON 1 - 7 ERLAUBT
        GOTO A010
     END
     IF &HOLZ EQ &ANZ THEN DO
        WRITE DAMIT HAETTEN SIE VERLOREN, SIE FLASCHE  -- BITTE NOCHMAL
        GOTO A010
     END
     SET &ANZ=&ANZ-&HOLZ
     IF &ANZ EQ 1 THEN GOTO A030
     WRITENR   ES BEIBEN &ANZ
A020:SET &X1=&ANZ//8
     IF &X1 < 2 THEN SET &X1=&X1 + 8
     SET &X1=&X1-1
     IF &X1 > 7 THEN +
        SET &X1=&EVAL(&SUBSTR(7:8,&SYSTIME))//7+1
     WRITENR   ICH NEHME &X1
     SET &ANZ=&ANZ-&X1
     IF &ANZ = 1 THEN GOTO A040
     WRITENR   ES BLEIBEN &ANZ
     GOTO A010
A030:WRITE
     WRITE       ****************************************************
     WRITE       *                                                  *
     WRITE       *            G R A T U L A T I O N                 *
     WRITE       * ICH MUSS DAS LETZTE HOLZ NEHMEN U. HABE VERLOREN *
     WRITE       *                                                  *
     WRITE       ****************************************************
     GOTO A050
A040:WRITE
     WRITE       *************************************************
     WRITE       *  IHRER SPIELWEISE NACH RIESELT IHNEN DER KALK *
     WRITE       *  BEREITS AUS DEN HOSENBEINEN.                 *
     WRITE       *                                               *
     WRITE       *  TRETEN SIE SOFORT DREI SCHRITTE ZURUECK,     *
     WRITE       *  SONST VERSTAUBEN MEINE MODULE !!!!           *
     WRITE       *************************************************
A050:WRITE
     WRITE
     WRITENR WOLLEN SIE NOCHMAL SPIELEN ?  J / N ===>
     READ
     IF &SYSDVAL EQ J THEN GOTO A000
END